spoke-okn

SPOKE-OKN

The spoke-okn (SPOKE Open Knowledge Network) KG is a comprehensive biomedical and environmental health knowledge graph that integrates diverse data across genomics, environmental science, and public health.

42.9M triples
8 classes
128 properties
4.8M subjects

The spoke-okn (SPOKE Open Knowledge Network) KG is a comprehensive biomedical and environmental health knowledge graph that integrates diverse data across genomics, environmental science, and public health. It encompasses multiple primary entity types, including organisms, geographic locations (from countries to ZIP codes), genes, diseases, chemical compounds, social determinants of health, and environmental contexts. With detailed hierarchical coverage of geographic information, spoke-okn supports spatial analyses of health outcomes, environmental exposures, and socioeconomic factors across a range of geographic scales.

Find compounds that downregulate genes associated with Alzheimer's disease. Return each gene's IRI and label (name) together with each compound's IRI and label (name), ordered alphabetically by gene name then compound name, limited to the first 10 results. [medium] 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX biolink: <https://w3id.org/biolink/vocab/>
PREFIX schema: <https://purl.org/okn/frink/kg/spoke-okn/schema/>

SELECT DISTINCT ?gene ?geneLabel ?compound ?compoundLabel {
    ?disease a biolink:Disease ;
             rdfs:label ?diseaseLabel .
    FILTER(LCASE(STR(?diseaseLabel)) = "alzheimer's disease")
    ?disease schema:ASSOCIATES_DaG ?gene .
    ?gene rdfs:label ?geneLabel .
    ?compound schema:DOWNREGULATES_CdG ?gene ;
              rdfs:label ?compoundLabel .
}
ORDER BY ?geneLabel ?compoundLabel
LIMIT 10

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v6("?compound"):::projected 
  v2("?compoundLabel"):::projected 
  v4("?disease")
  v3("?diseaseLabel")
  v5("?gene"):::projected 
  v1("?geneLabel"):::projected 
  c3([biolink:Disease]):::iri 
  f0[["lower-case(str(?diseaseLabel)) = 'alzheimer's disease'"]]
  f0 --> v3
  v4 --"a"-->  c3
  v4 --"rdfs:label"-->  v3
  v4 --"https://purl.org/okn/frink/kg/spoke-okn/schema/ASSOCIATES_DaG"-->  v5
  v5 --"rdfs:label"-->  v1
  v6 --"https://purl.org/okn/frink/kg/spoke-okn/schema/DOWNREGULATES_CdG"-->  v5
  v6 --"rdfs:label"-->  v2
Run in OKN
Find chemical compounds that treat rheumatoid arthritis. Return each compound's IRI and its label (name), ordered alphabetically by compound name, limited to the first 10 results. [easy] 
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX biolink: <https://w3id.org/biolink/vocab/>
PREFIX schema: <https://purl.org/okn/frink/kg/spoke-okn/schema/>

SELECT DISTINCT ?compound ?compoundLabel {
    ?disease a biolink:Disease ;
             rdfs:label ?diseaseLabel .
    FILTER(LCASE(STR(?diseaseLabel)) = "rheumatoid arthritis")
    ?compound schema:TREATS_CtD ?disease ;
              rdfs:label ?compoundLabel .
}
ORDER BY ?compoundLabel
LIMIT 10

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v4("?compound"):::projected 
  v1("?compoundLabel"):::projected 
  v3("?disease")
  v2("?diseaseLabel")
  c3([biolink:Disease]):::iri 
  f0[["lower-case(str(?diseaseLabel)) = 'rheumatoid arthritis'"]]
  f0 --> v2
  v3 --"a"-->  c3
  v3 --"rdfs:label"-->  v2
  v4 --"https://purl.org/okn/frink/kg/spoke-okn/schema/TREATS_CtD"-->  v3
  v4 --"rdfs:label"-->  v1
Run in OKN
Find drugs that treat diseases strongly associated with a social determinant of health (odds ratio > 5 and Fisher's exact p-value < 0.001 for the SDoH-disease co-occurrence). Return the SDoH name, disease name, odds ratio, Fisher's p-value, and compound name, ordered by descending odds ratio, limited to the first 10 results. [hard] 
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX schema: <https://purl.org/okn/frink/kg/spoke-okn/schema/>

SELECT DISTINCT ?sdohLabel ?diseaseLabel ?odds ?fisher ?compoundLabel {
    ?stmt rdf:subject ?sdoh ;
          rdf:predicate schema:ASSOCIATES_SaD ;
          rdf:object ?disease ;
          schema:odds ?odds ;
          schema:fisher ?fisher .
    FILTER(?odds > 5.0 && ?fisher < 0.001)
    ?compound schema:TREATS_CtD ?disease ;
              rdfs:label ?compoundLabel .
    ?sdoh rdfs:label ?sdohLabel .
    ?disease rdfs:label ?diseaseLabel .
}
ORDER BY DESC(?odds)
LIMIT 10

graph TD
classDef projected fill:lightgreen;
classDef literal fill:orange;
classDef iri fill:yellow;
  v6("?compound")
  v7("?compoundLabel"):::projected 
  v5("?disease")
  v9("?diseaseLabel"):::projected 
  v2("?fisher"):::projected 
  v1("?odds"):::projected 
  v4("?sdoh")
  v8("?sdohLabel"):::projected 
  v3("?stmt")
  c5([https://purl.org/okn/frink/kg/spoke-okn/schema/ASSOCIATES_SaD]):::iri 
  f0[["?odds > '5.0^^xsd:decimal'?fisher < '0.001^^xsd:decimal'"]]
  f0 --> v1
  f0 --> v2
  v3 --"rdf:subject"-->  v4
  v3 --"rdf:predicate"-->  c5
  v3 --"rdf:object"-->  v5
  v3 --"https://purl.org/okn/frink/kg/spoke-okn/schema/odds"-->  v1
  v3 --"https://purl.org/okn/frink/kg/spoke-okn/schema/fisher"-->  v2
  v6 --"https://purl.org/okn/frink/kg/spoke-okn/schema/TREATS_CtD"-->  v5
  v6 --"rdfs:label"-->  v7
  v4 --"rdfs:label"-->  v8
  v5 --"rdfs:label"-->  v9
Run in OKN
SPARQL Endpoint https://apps.okn.us/spoke-okn/sparql
Triple Pattern Fragments https://apps.okn.us/ldf/spoke-okn
ClassEntities
PropertyTriples